Problem z Klasą [Wolny Strzelec](exp + hp + pełny magazynek przy zabójstwie)

Mam problem próbuje dodać do tej klasy +30hp, +20exp oraz full magazynek za każde zabójstwo problem jest taki gdy dodam exp,hp i magazynek przy zabiciu wywala mi masę błedów przy kompilacji można prosić o pomoc?

Sma:

#include <amxmodx>
#include <amxmisc>
#include <codmod>
#include <fakemeta>
#include <fun>
        
new const nazwa[]   = "Wolny Strzelec";
new const opis[]    = "+30hp, +20 exp'a ,oraz pełen magazynek za każde zabójstwo, 2x skok";
new const bronie    = (1<<CSW_HEGRENADE)|(1<<CSW_USP)|(1<<CSW_M4A1);
new const zdrowie   = 50;
new const kondycja  = 30;
new const inteligencja = 5;
new const wytrzymalosc = 20;
    
new skoki[33];

new ma_klase[33];

public plugin_init()
{
	register_plugin(nazwa, "1.0", "amxx.pl");

	cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
   
	register_forward(FM_CmdStart, "fwCmdStart_MultiJump");

}

public cod_class_enabled(id)
{
	if(!(get_user_flags(id) & ADMIN_LEVEL_A))
	{
		client_print(id, print_chat, "[Wolny Strzelec] Nie masz uprawnien, aby uzywac tej klasy.")
		return COD_STOP;
	}
	give_item(id, "weapon_hegrenade");
	ma_klase[id] = true;
   
	return COD_CONTINUE;
}

public cod_class_disabled(id)
{
	ma_klase[id] = false;

}

public fwCmdStart_MultiJump(id, uc_handle)
{
	if(!is_user_alive(id) || !ma_klase[id])
		return FMRES_IGNORED;

	new flags = pev(id, pev_flags);

	if((get_uc(uc_handle, UC_Buttons) & IN_JUMP) && !(flags & FL_ONGROUND) && !(pev(id, pev_oldbuttons) & IN_JUMP) && skoki[id])
	{
		skoki[id]--;
		new Float:velocity[3];
		pev(id, pev_velocity,velocity);
		velocity[2] = random_float(265.0,285.0);
		set_pev(id, pev_velocity,velocity);
	}
	else if(flags & FL_ONGROUND)
		skoki[id] = 2;

	return FMRES_IGNORED;
}

Użytkownik Zastap edytował ten post 02.08.2013 14:11

W zmiennej MaxHP zwiekszasz maksymalna ilosc zycia ktora gracz moze posiadac...

 

#include <amxmodx>
#include <amxmisc>
#include <codmod>
#include <fakemeta>
#include <fun>
        
new const nazwa[]   = "Wolny Strzelec";
new const opis[]    = "+30hp, +20 exp'a ,oraz pełen magazynek za każde zabójstwo, 2x skok";
new const bronie    = (1<<CSW_HEGRENADE)|(1<<CSW_USP)|(1<<CSW_M4A1);
new const zdrowie   = 50;
new const kondycja  = 30;
new const inteligencja = 5;
new const wytrzymalosc = 20;
    
new skoki[33];

new ma_klase[33];

new MaxHP = 200;

public plugin_init()
{
    register_plugin(nazwa, "1.0", "amxx.pl");

    cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
   
    register_forward(FM_CmdStart, "fwCmdStart_MultiJump");
    
    register_event("DeathMsg", "DeathMsg", "a");

}

public cod_class_enabled(id)
{
    if(!(get_user_flags(id) & ADMIN_LEVEL_A))
    {
        client_print(id, print_chat, "[Wolny Strzelec] Nie masz uprawnien, aby uzywac tej klasy.")
        return COD_STOP;
    }
    give_item(id, "weapon_hegrenade");
    ma_klase[id] = true;
   
    return COD_CONTINUE;
}

public cod_class_disabled(id)
{
    ma_klase[id] = false;

}

public fwCmdStart_MultiJump(id, uc_handle)
{
    if(!is_user_alive(id) || !ma_klase[id])
        return FMRES_IGNORED;

    new flags = pev(id, pev_flags);

    if((get_uc(uc_handle, UC_Buttons) & IN_JUMP) && !(flags & FL_ONGROUND) && !(pev(id, pev_oldbuttons) & IN_JUMP) && skoki[id])
    {
        skoki[id]--;
        new Float:velocity[3];
        pev(id, pev_velocity,velocity);
        velocity[2] = random_float(265.0,285.0);
        set_pev(id, pev_velocity,velocity);
    }
    else if(flags & FL_ONGROUND)
        skoki[id] = 2;

    return FMRES_IGNORED;
}

public DeathMsg()
{

    new killer=read_data(1);
    new victim=read_data(2);
    
    if(is_user_alive(killer) && ma_klase[killer] && get_user_team(killer) != get_user_team(victim))
    {
    
        Dodawanko(killer, victim);

    }
    
}

public Dodawanko(kid, vid)
{

    set_user_health(kid, min(get_user_health(kid)+30, MaxHP));
    cod_set_user_xp(kid, cod_get_user_xp(kid)+20);
    give_item(kid, "ammo_556nato");
    give_item(kid, "ammo_45acp");

}

Dziękuje +'ik
Close

Użytkownik Zastap edytował ten post 02.08.2013 15:20