[ROZWIĄZANE] Return PLUGIN_CONTINUE, co dalej?

Funkcja return bez względu na zwracaną wartość, przerywa wywołanie funkcji.

• PLUGIN_CONTINUE zwracasz, by po prostu zakończyć działanie funkcji.
  Zwrócenie tej wartości nic ponad przerwaniem wywołania funkcji, nie zmienia.
• PLUGIN_HANDLED zwracasz, by uniemożliwić dalsze wykonanie danej komendy,
  danego zdarzenia czy innego hooka. Przerwany hook nie objawi się ani w grze
  ani w żadnym z kolejnych wywołań hooka, także w innych pluginach.
• PLUGIN_HANDLED_MAIN zwracasz, by uniemożliwić dalsze wykonanie danej komendy,
  danego zdarzenia czy innego hooka jedynie w silniku gry podczas, gdy każde kolejne
  wywołanie hooka, także przez inne pluginy, będzie dalej możliwe do wykonania.

Innymi słowy,

• PLUGIN_CONTINUE nie robi nic,
• PLUGIN_HANDLED przerywa dalsze działanie i dla silnika i dla innych pluginów
• PLUGIN_HANDLED_MAIN przerywa działanie tylko dla silnika, nie dla innych pluginów

Ponadto warto zauważyć, że istotna jest kolejność pluginów w pliku plugins.ini
Mając przykładowo takie pluginy:

#include <amxmodx>

public plugin_init(){
    register_plugin("no say", "0.1", "test");
    register_clcmd("say","say");
}

public say(id){
    return PLUGIN_HANDLED;
}

#include <amxmodx>

public plugin_init(){
    register_plugin("clean say", "0.1", "test");
    register_clcmd("say","say");
}

public say(id){
    new Speech[192];
    read_args(Speech,191);
    remove_quotes(Speech);
    if(is_user_alive(id) && equali(Speech, "brzydkie_slowo")){
        user_kill(id);
        return PLUGIN_HANDLED;
    }
    return PLUGIN_CONTINUE;
}

Pierwszy plugin całkowicie blokuje say (PLUGIN_HANDLED), drugi natomiast blokuje jedynie brzydkie słowa (PLUGIN_HANDLED),
karząc śmiercią, pozostałe zaś przepuszczając (pozwalając na ich wypowiedzenie) (PLUGIN_CONTINUE).

Jeśli pierwszy plugin będzie u góry, to najpierw zostanie wysłana wartość PLUGIN_HANDLED, która drugiemu pluginowi
nie pozwoli ukarać śmiercią w przypadku brzydkich słów (wcześniej została zwrócona wartość PLUGIN_HANDLED).

Jeśli pluginy byłyby w odwrotnej kolejności, to brzydkie słowa
zostałyby nagrodzone śmiercią, a cały say i tak zablokowany.

To był przykład na istotę kolejności dodawanych pluginów w plugins.ini w powiązaniu z tematyką wątku.