/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <fun>
#include <hamsandwich>
#include <codmod>
#include <colorchat>

#define CZAS_GODMOD 2 //SEKUND

new const nazwa[] = "Powstaniec";
new const opis[] = "Ma 2 sekundy niesmiertelnosci co runde, dodatkowe 10 procent obrazen z mac10";
new const bronie = 1<<CSW_MAC10 | 1<<CSW_HEGRENADE;
new const zdrowie = 0;
new const kondycja = 10;
new const inteligencja = 0;
new const wytrzymalosc = 0;

new bool:wykorzystal[33];
new bool:ma_klase[33];

new msg_bartime;

public plugin_init() {
	register_plugin(nazwa, "1.0", "QTM_Peyote");
	
	cod_register_class(nazwa, opis, bronie, zdrowie, kondycja, inteligencja, wytrzymalosc);
	
	register_event("ResetHUD", "ResetHUD", "abe");
	
	RegisterHam(Ham_TakeDamage, "player", "TakeDamage");
	
	msg_bartime = get_user_msgid("BarTime");
}

public cod_class_enabled(id)
{
	ma_klase[id] = true;
	ResetHUD(id);
}

public cod_class_disabled(id)
	ma_klase[id] = false;

public cod_class_skill_used(id)
{
	if(!is_user_alive(id))
		return;
		
	if(wykorzystal[id])
	{
		ColorChat(id, GREEN, "[Powstaniec] ^x01 Wykorzystales juz swoja niesmiertelnosc.");
		return;
	}
	
	wykorzystal[id] = true;
	
	set_user_godmode(id, 1);
	set_user_rendering(id, kRenderFxGlowShell, 255, 0, 0);
	set_task(CZAS_GODMOD.0, "WylaczGod", id);
	
	message_begin(MSG_ONE, msg_bartime, _, id)
	write_short(CZAS_GODMOD)
	message_end()
}

public WylaczGod(id)
{
	if(!is_user_connected(id)) return;
	
	set_user_godmode(id, 0);
	set_user_rendering(id, kRenderFxGlowShell, 0, 0, 0);
}

public ResetHUD(id)
	wykorzystal[id] = false;

public TakeDamage(this, idinflictor, idattacker, Float:damage, damagebits)
{
	if(!is_user_connected(idattacker))
		return HAM_IGNORED;
	
	if(!ma_klase[idattacker])
		return HAM_IGNORED;
	
	if(!(damagebits & (1<<1)))
		return HAM_IGNORED;
		
	if(get_user_weapon(idattacker) != CSW_MAC10)
		return HAM_IGNORED;
		
	cod_inflict_damage(idattacker, this, damage*0.1, 0.0, idinflictor, damagebits);
		
	return HAM_IGNORED;
}
