
 public String_Shot(id, skill, prop)
 {
	new victim = PokeSkillTarget(id);
	if( is_user_alive(victim) && Chance(id) && !g_Status[victim][STATUS_SLOW]){
		poke_print(victim,print_center,"Zostales uderzony String Shot")
		poke_print(id,print_center,"Zaatakowales kogos z String Shot")

		ApplyStatus( id, victim, STATUS_SLOW, STRING_SHOT_TIME )

		sound_hit(id)
		sound_hit(victim)

		MakeLine_Ent(0,id,victim,SPRITE_INDEX[SPR_ARBOK],1,1,10,10,0,89,89,89,100,0)

		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
 }
 public Leech_Life(id, skill, prop)
 {
	new victim = PokeSkillTarget(id);
	if( !is_user_alive(victim) )
		return PLUGIN_CONTINUE;
	poke_print(victim, print_center, "Ktos wysysa z ciebie zycie")
	return Heal(id, skilldamage(victim, id, LEECHLIFE, skill) );
 }
 public Pin_Missile(id, skill, prop)
 {
	new Float: origin[3], Float: aim[3], Float: velocity[3], Ent

	pev(id, pev_origin, origin)
	pev(id, pev_v_angle, aim)

	Ent = fm_create_entity("info_target")

	if (!Ent) return PLUGIN_CONTINUE;

	set_pev(Ent, pev_classname, "poke_attack")
	set_pev(Ent, pev_iuser1, PIN_MISSLE_DAMAGE)
	set_pev(Ent, pev_iuser2, skill)
	fm_entity_set_model(Ent, MODELS[MDL_ROCKET])

	new Float:MinBox[3] = {-3.0, -3.0, -3.0}
	new Float:MaxBox[3] = {3.0, 3.0, 3.0}
	set_pev(Ent, pev_mins, MinBox)
	set_pev(Ent, pev_maxs, MaxBox)

	fm_entity_set_origin(Ent, origin)

	set_pev(Ent, pev_angles, aim)

	set_pev(Ent, pev_solid, SOLID_TRIGGER)
	set_pev(Ent, pev_movetype, MOVETYPE_FLY)
	set_pev(Ent, pev_owner, id)

	velocity_by_aim(id, PIN_MISSLE_VEC , velocity)
	set_pev(Ent, pev_velocity, velocity)

	// Trail on enity.
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(TE_BEAMFOLLOW)		// TE_BEAMFOLLOW
	write_short(Ent)	// entity:attachment to follow
	write_short(SPRITE_INDEX[SPR_MUZZLEFLASH1])	// sprite index
	write_byte(10)	// life in 0.1's
	write_byte(5)		// line width in 0.1's
	write_byte(255)	//r,g,b
	write_byte(255)
	write_byte(255)
	write_byte(255)	// brightness
	message_end()

	poke_sound(id,CHAN_VOICE,SND_TU_FIRE)
	return PLUGIN_HANDLED;
 }