 public Counter(id, skill, prop)
 {
	new victim = PokeSkillTarget(id);
	if( is_user_alive(victim) && MaxChance(id,rage[id]) ){
		poke_sound(id, CHAN_VOICE, SND_BODYDROP);
		poke_print(id,print_center,"Twoj kontr-atak zadal %d obrazen", skilldamage( victim, id, rage[id]/COUNTER_FACTOR, skill))
		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
 }
 public Karate_Chop(id, skill, prop)
 {
	new weapon, victim = PokeSkillTarget(id, _, weapon);
	if( is_user_alive(victim) && knife_weapon( weapon ) ){
		poke_sound(id, CHAN_VOICE, SND_BODYDROP);
		skilldamage(victim, id, KARATE_CHOP, skill);
		screenflash(victim, 0, 0, 0, 255, 1.0);
		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
 }
 public Submission(id, skill, prop)
 {
	new victim = PokeSkillTarget(id);
	if( is_user_alive(victim) ){
		poke_sound(id, CHAN_VOICE, SND_BODYDROP);
		ApplyStatus( id, victim, STATUS_PARALYZE, SUBMISSION_TIME );
		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
 }
 public Take_Down(id, skill, prop)
 {
	new victim = PokeSkillTarget(id);
	if( is_user_alive(victim) ){
		poke_sound(id, CHAN_VOICE, SND_BODYDROP);
		ApplyStatus( id, victim, STATUS_PARALYZE, TAKE_DOWN_TIME );
		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
 }
 public Low_Kick(id, skill, prop)
 {
	new victim = PokeSkillTarget(id);
	if( is_user_alive(victim) ){
		poke_sound(id, CHAN_VOICE, SND_BODYDROP);
		skilldamage(victim, id, LOW_KICK, skill);

		new ran = random_num(1,180), Float:look[3];
		pev(victim, pev_angles, look);
		if(look[0]<180) look[0] += ran;
		else look[0] -= ran;
		ran = random_num(1,180);
		if(look[1]<180) look[1] += ran;
		else look[1] -= ran;
		set_pev(victim, pev_angles, look);
		set_pev(victim, pev_fixangle, 1);

		return PLUGIN_HANDLED;
	}
	return PLUGIN_CONTINUE;
 }
 public Seismic_Toss(id, skill, prop)
 {
	new victim = PokeSkillTarget(id);
	if( !is_user_alive(victim) || !fm_is_ent_visible(id, victim) )
		return PLUGIN_CONTINUE;

	new Float:velocity[3];
	velocity_by_aim(id, SEISMIC_TOSS, velocity);
	velocity[2] = floatmax(velocity[2], 50.0);

	set_pev(victim, pev_velocity, velocity);
	skilldamage(victim, id, SEISMIC_TOSS_DAMAGE, skill);
	return PLUGIN_HANDLED;
 }